flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104

{
  description = "Amir's Home Manager";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";
    home-manager.url = "github:nix-community/home-manager/release-26.05";
    unstable.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    nixgl.url = "github:nix-community/nixGL";
    nixvim.url = "github:nix-community/nixvim/nixos-26.05";
    sctd.url = "github:amir/sctd";
  };

  outputs =
    {
      self,
      nixpkgs,
      home-manager,
      unstable,
      flake-utils,
      nixgl,
      nixvim,
      sctd,
      ...
    }:
    let
      mkExtraArgs = system: {
        unstablePkgs = import unstable {
          inherit system;
          config.allowUnfree = false;
        };
        unfreePkgs = import nixpkgs {
          inherit system;
          config.allowUnfree = true;
        };
        unstableUnfreePkgs = import unstable {
          inherit system;
          config.allowUnfree = true;
        };
      };

      mkHostConfig =
        {
          hostname,
          system ? "aarch64-darwin",
        }:
        {
          pkgs = import nixpkgs {
            inherit system;
            overlays = [
              nixgl.overlay
              sctd.overlays.default
            ];
            config = {
              allowUnfree = false;
            };
          };
          modules = [
            ./hosts/${hostname}/home.nix
            nixvim.homeModules.nixvim
            sctd.homeManagerModules.default
          ];
          extraSpecialArgs = (mkExtraArgs system) // {
            inherit hostname;
            hmLib = home-manager.lib;
          };
        };
    in
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          config = {
            allowUnfree = false;
          };
        };
      in
      {
        packages = {
          default = home-manager.packages.${system}.home-manager;
        };

        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs; [
            #home-manager
            home-manager.packages.${system}.home-manager
            nixpkgs-fmt
          ];
        };
      }
    )
    // {
      homeConfigurations = {
        mentat = home-manager.lib.homeManagerConfiguration (mkHostConfig {
          hostname = "mentat";
        });
        gheshki = home-manager.lib.homeManagerConfiguration (mkHostConfig {
          hostname = "gheshki";
          system = "x86_64-linux";
        });
      };
    };
}